Glad to hear you're interested in this! MBPU's challenges use TorqueScript, which is the scripting language used for most of the game logic in Marble Blast. The code is in .chl files, which are located in the marble/data/challenges directory. Let's take a look into some of these.
Here's bounce_parallax.chl, the first challenge you mention:
Code:
new ScriptObject(ChallengeInfo) {
artist = "Whirligig231";
name = "Parallax";
mission = "beginner/bounce.mis";
desc = "You're afraid of green ... and yellow too ...";
diff = 3;
};
banGreen();
function onUnload() {
resetBan();
}
The new ScriptObject bit is just to give the name, author, level, and difficulty of the challenge. The meat of the code is the banGreen and resetBan functions. The former will disallow you from touching any green textures; this is done by giving those textures ridiculously large negative friction (similar to the Random Force in MBP). The latter restores the friction to normal.
Now, here's windingroad_madness.chl, the Winding Madness challenge:
Code:
new ScriptObject(ChallengeInfo) {
artist = "Whirligig231";
name = "Winding Madness";
mission = "beginner/windingroad.mis";
desc = "The camera has gone a bit ... mad ... Try an isometric view!";
diff = 2;
};
function onSpawn() {
schedule(100,0,"resetCamThing");
}
function resetCamThing() {
defaultmarble.cameraDistance = 100;
defaultmarble.cameraMaxFov = 10;
defaultmarble.cameraMinFov = 10;
}
$tempEffects = $pref::disablePowerupEffects;
$pref::disablePowerupEffects = 1;
%smat = MatrixMultiply("0 0 0" SPC getWords(StartPoint.rotation,0,2) SPC mDegToRad(getWords(StartPoint.rotation,3)), "0 0 0 0 0 -1 0.78539816229745");
%emat = MatrixMultiply("0 0 0" SPC getWords(EndPoint.rotation,0,2) SPC mDegToRad(getWords(EndPoint.rotation,3)), "0 0 0 0 0 -1 0.78539816229745");
StartPoint.rotation = getWords(%smat,3,5) SPC mRadToDeg(getWords(%smat,6));
EndPoint.rotation = getWords(%emat,3,5) SPC mRadToDeg(getWords(%emat,6));
disable("turnleft");
disable("turnright");
disable("turnup");
disable("turndown");
function onUnload() {
defaultmarble.cameraDistance = 2.5;
defaultmarble.cameraMaxFov = 90;
defaultmarble.cameraMinFov = 90;
enableAll();
$pref::disablePowerupEffects = $tempEffects;
}
The onSpawn function just schedules resetCamThing to take place 100 ms after you spawn, as it has to wait until the camera is properly initialized and all. The resetCamThing function then zooms the camera out and decreases the field of view, simulating an orthographic view. Then the next two lines, outside the function, make sure powerup effects are disabled, remembering whether they were previously on so they can be re-enabled if necessary. After that, the next four lines, with matrices, rotate the start and end pads 45 degrees so they face a different direction. This involves a lot of complicated math. The next four lines disable all of the camera rotation controls. Finally, the onUnload function resets everything back to normal.
Here's the bumper swarm code:
Code:
new ScriptObject(ChallengeInfo) {
artist = "Whirligig231";
name = "Bumper School";
mission = "beginner/bumpers.mis";
desc = "You might be a bit ... swarmed.";
diff = 1;
};
schedule(3000,0,"withAll","Bumpers","%this.approachObject(p(),5);");
Apart from the challenge info, this can actually be done in one line! This uses three functions at a time. The first is schedule(), which waits three seconds before the bumpers start to move. The second is withAll, which executes the code "%this.approachObject(p(),5);" for each of the bumpers in the level. The third is the approachObject method, which automatically sets up a loop causing the bumper to slowly approach the marble at a speed of 5. The function p() is shorthand for LocalClientConnection.getControlObject(), which gets the marble.
Here's the fan sucking code:
Code:
new ScriptObject(ChallengeInfo) {
artist = "Whirligig231";
name = "This Challenge Sucks!";
mission = "beginner/ductfan.mis";
desc = "Dude, it really sucks!";
diff = 2;
};
DuctFan.forceStrength[0] = -100;
Again, this is one line: we change the strength of the DuctFan to be negative, so that it pulls you in instead of blowing you away. We don't need to reset this in onUnload, because properties of level objects get re-initialized every time you load a new level.
You can make your own challenges simply by making more .chl files. You'll need to know some amount of TorqueScript (or beg someone to do the code for you). The important part is the ChallengeInfo object.
artist is the author's name,
name is the name of the challenge,
mission is the path to the level file you want the challenge to work with,
beginning from the marble/data/missions directory,
desc is the description of the challenge, and
diff is the number of difficulty stars. Let me know if you have any issues or questions.
How Can I Create A Special Challenge For A Custom Level?
